Add Sprite3D and AnimatedSprite3D demo (#1191)

3d/sprites/scripts/3d_sprites.gd

@@ -0,0 +1,70 @@
+extends Node
+
+const ROT_SPEED = 0.003
+const ZOOM_SPEED = 0.125
+const MAIN_BUTTONS = MOUSE_BUTTON_MASK_LEFT | MOUSE_BUTTON_MASK_RIGHT | MOUSE_BUTTON_MASK_MIDDLE
+
+var tester_index := 0
+var rot_x := -TAU / 16  # This must be kept in sync with RotationX.
+var rot_y := TAU / 6  # This must be kept in sync with CameraHolder.
+var camera_distance := 3.4
+var base_height := int(ProjectSettings.get_setting("display/window/size/viewport_height"))
+
+@onready var testers: Node3D = $Testers
+@onready var camera_holder: Node3D = $CameraHolder  # Has a position and rotates on Y.
+@onready var rotation_x: Node3D = $CameraHolder/RotationX
+@onready var camera: Camera3D = $CameraHolder/RotationX/Camera3D
+
+
+func _ready() -> void:
+	camera_holder.transform.basis = Basis.from_euler(Vector3(0, rot_y, 0))
+	rotation_x.transform.basis = Basis.from_euler(Vector3(rot_x, 0, 0))
+	update_gui()
+
+
+func _unhandled_input(event: InputEvent) -> void:
+	if event.is_action_pressed(&"ui_left"):
+		_on_previous_pressed()
+	if event.is_action_pressed(&"ui_right"):
+		_on_next_pressed()
+
+	if event is InputEventMouseButton:
+		if event.button_index == MOUSE_BUTTON_WHEEL_UP:
+			camera_distance -= ZOOM_SPEED
+		if event.button_index == MOUSE_BUTTON_WHEEL_DOWN:
+			camera_distance += ZOOM_SPEED
+		camera_distance = clamp(camera_distance, 1.5, 6)
+
+	if event is InputEventMouseMotion and event.button_mask & MAIN_BUTTONS:
+		# Compensate motion speed to be resolution-independent (based on the window height).
+		var relative_motion: Vector2 = event.relative * DisplayServer.window_get_size().y / base_height
+		rot_y -= relative_motion.x * ROT_SPEED
+		rot_x -= relative_motion.y * ROT_SPEED
+		rot_x = clamp(rot_x, -1.57, 0)
+		camera_holder.transform.basis = Basis.from_euler(Vector3(0, rot_y, 0))
+		rotation_x.transform.basis = Basis.from_euler(Vector3(rot_x, 0, 0))
+
+
+func _process(delta: float) -> void:
+	var current_tester: Node3D = testers.get_child(tester_index)
+	# This code assumes CameraHolder's X and Y coordinates are already correct.
+	var current_position := camera_holder.global_transform.origin.z
+	var target_position := current_tester.global_transform.origin.z
+	camera_holder.global_transform.origin.z = lerpf(current_position, target_position, 3 * delta)
+	camera.position.z = lerpf(camera.position.z, camera_distance, 10 * delta)
+
+
+func _on_previous_pressed() -> void:
+	tester_index = max(0, tester_index - 1)
+	update_gui()
+
+
+func _on_next_pressed() -> void:
+	tester_index = min(tester_index + 1, testers.get_child_count() - 1)
+	update_gui()
+
+
+func update_gui() -> void:
+	$TestName.text = str(testers.get_child(tester_index).name).capitalize()
+	$Previous.disabled = tester_index == 0
+	$Next.disabled = tester_index == testers.get_child_count() - 1

3d/sprites/scripts/3d_sprites.gd.uid

@@ -0,0 +1 @@
+uid://v0e1avxpe8n7

3d/sprites/scripts/player.gd

@@ -0,0 +1,27 @@
+extends Node3D
+
+@onready var sprite: AnimatedSprite3D = $AnimatedSprite3D
+@export var move_speed: float = 5.0
+
+var velocity: Vector3 = Vector3.ZERO
+
+
+func _process(delta: float) -> void:
+	var input_vector: Vector2 = Vector2.ZERO
+
+	input_vector.x = Input.get_action_strength("move_right") - Input.get_action_strength("move_left")
+	input_vector.y = Input.get_action_strength("move_back") - Input.get_action_strength("move_forward")
+
+	if input_vector.length() > 0:
+		input_vector = input_vector.normalized()
+		# Update player's position in 3D space.
+		velocity = Vector3(input_vector.x, 0, input_vector.y) * move_speed
+		translate(velocity * delta)
+
+		# Play corresponding animation.
+		if abs(input_vector.x) > abs(input_vector.y):
+			sprite.play("walk_right" if input_vector.x > 0 else "walk_left")
+		else:
+			sprite.play("walk_down" if input_vector.y > 0 else "walk_up")
+	else:
+		sprite.stop()

3d/sprites/scripts/player.gd.uid

@@ -0,0 +1 @@
+uid://c7bu02ppdx1v5

3d/sprites/scripts/sprite_rotate.gd

@@ -0,0 +1,7 @@
+extends Sprite3D
+
+@export var speed_deg: float = 90.0
+
+
+func _process(delta: float) -> void:
+	rotate_y(deg_to_rad(speed_deg * delta))

3d/sprites/scripts/sprite_rotate.gd.uid

@@ -0,0 +1 @@
+uid://bmij60kwbx48u